Запуск виртуального linux с помощью qemu в windows

вот как я запускаю минимальную версию CentOS 7 на Windows 7 Enterprise, 64 бит, не будучи членом группы администраторов (без прав администратора).

основная идея:

1. скачать qemu для windows и распаковать его в любом месте
2. скачать ISO-образ дистрибутива Linux, который вы хотите запустить
3. создать файл, который будет ваша виртуальная машина жесткий диск
4. запустить qemu, загрузка с компакт-диска image
5. установить ОС
6. перезагрузите виртуальную машину, на этот раз без компакт-диска

сеть и причудливые графики трудно получить право. Все еще борется, вообще-то...

1. Скачать QEMU

использовать скомпилированные двоичные файлы нашли на QEMU ссылки. Я использовал версия 2.8.0 для этого.

чтобы "установить" эту версию без прав администратора, откройте команду подскажите, выполните команду set __COMPAT_LAYER=RunAsInvoker и работать qemu-w64-setup-20170131.exe из этого приглашения. Установите в папку, где у вас есть разрешения на запись, например "Мои Документы" или что-то еще.

2. Скачать ISO образ Linux

опять же, помочь себе. Я использовал минимальное распределение CentOS 7 файл называется CentOS-7-x86_64-Minimal-1611.iso.

3. Создайте виртуальный жесткий диск

я использовал пакетный файл для этого. Скопируйте следующее в файл с именем createvm.bat и настроить переменные в соответствии с вашей средой:

@echo off
rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem Safety net
rem ==================================
if not exist hda.img (
    rem CREATE a virtual hard disk 
    %QEMUDIR%\qemu-img.exe create hda.img 40G
) else (
    echo file hda.img already exist. Delete or move and try again.
    goto:eof
)

4. Запустите QEMU, загрузившись с виртуального CD

используйте пакет для этого, так как вы можете использовать его часто. Скопируйте follwing в installvm.bat:

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"
set "ISOFILE=CentOS-7-x86_64-Minimal-1611.iso"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -cdrom %ISOFILE% -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot 

5. Установка операционной системы

у меня были проблемы с установщиком GUI. Когда будет предложено установить CentOS, нажмите TAB ключ и заменить слово quiet в конце этой строчки со словом text.

следуйте инструкциям по установке на экране. По завершении установки виртуальная машина завершит работу. Это может занять некоторое время, особенно при работе в качестве пользователя без прав администратора.

6. Запустите образ Linux в QEMU

этот шаг что вы будете делать снова и снова, чтобы запустить виртуальную машину каждый раз, когда вам это нужно. Скопируйте follwing в runvm.bat:

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot -device e1000,netdev=user.0 -netdev user,id=user.0,hostfwd=tcp::2222-:22

я добавил местный portforward: если вы ssh / putty на localhost: 2222, вы достигнете демона SSH вашей виртуальной машины. Остерегайся этого firewalld или iptables может блокировать трафик, в зависимости от способа установки Linux.