Есть ли способ подключить образ Тома EXT4 в Windows 7?

OSFMount http://www.osforensics.com/tools/mount-disk-images.html

OSFMount позволяет монтировать файлы образа локального диска в Windows с помощью буква диска.

отлично подходит для монтирования образа Ext4 в windows, и загрузка составляет всего 2 МБ.

о:

• Mount Image Pro v6 [https://dailyuploads.net/ewmo7ypfr1m5] (^- мочь только получить его для запуска этой версии с патчем Anti Dongle)
  
  но Mount Image Pro не может монтировать файлы Ext4 (это просто хорошо для *.ИСО.* ,dmg,*.vhd и еще несколько криминалистических изображений)

• FTK Imager 3.4.3 http://ad-exe.s3.amazonaws.com/AccessData_FTK_Imager_3.4.3_x64.exe Ну я своего рода та же история - все виды поддержки CD-образ, но ни для Ext4

OSFMount нет Поддержка падение-Н-'drag - также использованиеOSFMount.com не так просто связать его с *.ext4 или *.img файлы для их монтирования. (требуются дополнительные параметры) Итак, вот cmd-скрипт OSFMount.cmd

    @prompt -$G

    @echo OSFMount Script 1.0
    @echo ===================
    @echo.

    @set OSFMount_Exe=OSFMount.com
    @set OSFMount_Path="%programFiles%\OSFMount\%OSFMount_Exe%"

    @set MaxDrivesCount=4
    @set MountPoint=#:

    @set options=ro

    @set g_MuteOutput= ^>nul 2^>^&1


    @Call :CheckNSet_PathToExe

    @Call :MayBe_UnMountAll


    ::if "%2" NEQ "" set MountPoint=%2
    @set File=%1
    @set cmd=%OSFMount% -a -t file -m %MountPoint% -f "%File%" -o %options%

    @%cmd%
    @if Errorlevel 1 @(
        @echo Errorlevel: %Errorlevel%
        @call :UnMountAll
        %cmd%
    )


::  %g_MuteOutput% 

::  @pause

@goto :eof

:CheckNSet_PathToExe
    @call :SetIfExist OSFMount %OSFMount_Path%
    @if not defined OSFMount @(

        @call :SetIfExist OSFMount "%~dp0%OSFMount_Exe%"
        @if not defined OSFMount @(

            @echo ERROR: %OSFMount% not found!
            @echo.
            @echo Please copy %~nx0 into same dir where %OSFMount_Exe% is!
            @exit
        )

    )
@goto :eof

:SetIfExist
    @if exist "%~2" set %1="%~2"
@goto :eof




:MayBe_UnMountAll
    :: GetNumberOf (EXT4) Drives
    :: Well OSFMount can also mount other types but this is some kind of compromise or now  
    @set g_CountLines= ^^^| find /c  "="
    @set g_Drives=wmic logicaldisk where FileSystem^^^="EXT4" get Name /value

    @for /f %%x in ('%g_Drives% %g_CountLines%') do @set Lines=%%x

    @echo   Currently mounted drives %Lines% \ %MaxDrivesCount%

    @if %lines% GEQ %MaxDrivesCount% @call :UnMountAll


@goto :eof


:UnMountAll
    @for /f "tokens=2 delims==" %%d in (
        '%g_Drives%' 
        ) do @(
    @call :UnMount %%d
    )

    @prompt -$G

@goto :eof

:UnMount

    @%OSFMount% -D -m %1 %g_MuteOutput% 
    @if not errorlevel 1 @echo %1 UnMounted!


    @goto :eof

установка:

1. копировать / вставить и сохранить как OSFMount.cmd (в блокноте или каком-нибудь более приятном редакторе)
2. и поместите его в тот же каталог, что и OSFMount.com. (хорошо, если OSFMount установлен в "C:\program files\OSFMount" вы можете и положи в другое место.)
3. создать ссылку на рабочий стол или панель быстрого запуска

использование:

• монтировать образ просто перетащите его в OSFMount.cmd (или ссылку).
• ассоциация файлов также просто-просто выберите OSFMount.cmd в диалоговом окне "открыть с помощью".

пример использования командной строки : OSFMount.cmd d:\android-5.1-rc1\system.img

следующая свободная буква диска выбирается автоматически. Если вы смонтировали более 4 образов, скрипт сбросит и размонтирует остальные. (Измените строку с MaxDrivesCount=4 в сценарии, если вам нужно больше или меньше. )

пока что скрипт тестируется только с ext4 изображениями. Для работы с другими типами образов, такими как iso, vhd, вы, вероятно, можете изменить сценарий.