Как отключить/включить буфер обмена Office

отключение буфера обмена

ниже метод обхода, чтобы отключить функциональность буфера обмена с помощью скрипт С некоторой условной логикой и петлей. Там также метод и некоторые инструкции ниже, что изложение, как легко убить цикл. Он использует некоторые динамические язык сценариев VB, чтобы помочь сохранить процесс скрыт в фоновом режиме во время работы, но он по-прежнему дает вам контроль, чтобы использовать его и убить его, как необходимый.

Скрипт

IF /I [%~N1]==[KillSwitch] TASKKILL /F /FI "WindowTitle eq ClearClip" & EXIT
IF NOT DEFINED MINIMIZED SET MINIMIZED=1 && START "" /MIN "%~F0" x && EXIT
@ECHO OFF
IF NOT [%~1]==[] GOTO :VBProcess

TITLE ClearClip
:LoopIt
ping -n 02 127.0.0.1 > nul

:WipeClip
cmd.exe /c echo off | clip
GOTO :LoopIt

:VBProcess
SET TempVBSFile=%temp%\~tmpVBSTemp.vbs
IF EXIST "%TempVBSFile%" DEL /F /Q "%TempVBSFile%"

ECHO Set WinScriptHost = CreateObject("WScript.Shell") >"%TempVBSFile%"
ECHO WinScriptHost.Run Chr(34) ^& "%~F0" ^& Chr(34), 0 >>"%TempVBSFile%"
ECHO Set WinScriptHost = Nothing                       >>"%TempVBSFile%"

CSCRIPT //nologo "%TempVBSFile%"
EXIT

по сути это. . .

• убивает все процессы с названием "ClearClip" Если "KillSwitch" по имени файла передается в качестве первого аргумента и затем полностью завершает работу скрипта (см. убить его с помощью Kill Switch)

• запускает [сам] пакетный скрипт снова, но минимизируется и с пройденным манекеном"x" значение первого аргумента

• начинается [сам] пакетный скрипт скрытый динамический скрипт VB, если первый аргумент не null, а затем петли каждые 2 секунды очистки буфера обмена

использовать

чтобы использовать его или включить функциональность, чтобы очистить буфер обмена каждые 2 секунды, просто дважды щелкните или выполните пакетный скрипт. Если у вас возникли проблемы или он не работает, как ожидалось, попробуйте запуск его с повышенными правами администратора с помощью простого щелкните правой кнопкой мыши / Запуск от имени администратора.

убить его выключателем

1. создайте файл с именем KillSwitch.txt и поместите его рядом с пакетного сценария вы сохранили, что вы выполняете, чтобы отключить буфер обмена

2. перетащить KillSwitch.txt имя файла прямо в или на скрипт, который вы выполняете, чтобы отключить буфер обмена, и это убьет скрытые фоновые процессы, которые очищают буфер обмена, а затем буфер обмена будет доступен снова.

   

   

далее Ресурсы

• If
• Start
• Goto
• Title
• .Беги

• CScript

• CALL /?

  Substitution of batch parameters (%n) has been enhanced.  You can
  now use the following optional syntax:
  
      %~1         - expands %1 removing any surrounding quotes (")
      %~f1        - expands %1 to a fully qualified path name
      %~n1        - expands %1 to a file name only
  

• автоматически очистить буфер обмена с ClipTTL