Как запускать приложения автоматически после монтирования контейнера TrueCrypt?

Я знаю, что этот вопрос стар, но он находится высоко в списке поиска, поэтому я бы опубликовал свое решение.

я монтирую диск и запускаю свои программы с помощью a .Bat-файл. Я запускаю .bat файл в назначенные задания "на входе".

вот моя бита. Наслаждаться.

Примечание вы должны установить truecrypt автоматически не монтировать ваши "избранное" и есть situtation, что следующая летучая мышь не обрабатывает: когда том монтируется в альтернативная буква диска, чем указано.

REM - Truecrypt mount and launch file - 2013
REM - Set variables as needed below
@ECHO OFF

SET tcexec="%PROGRAMFILES%\truecrypt\truecrypt.exe"
SET mountdrive=x
SET volumefolder="%USERPROFILE%\truecrypt"
SET volumename=TrueCrypt-Volume

IF EXIST %mountdrive%: goto DriveExists

IF NOT EXIST %volumefolder%\%volumename% goto NoVolume

IF NOT EXIST %tcexec% goto noTC

REM Mount volume
cd %volumefolder%
%tcexec% /v %volumename% /l%mountdrive% /a /q
echo %ERRORLEVEL%
if ERRORLEVEL 1 GOTO mountfail
if ERRORLEVEL 0 GOTO startprograms

:startprograms
REM ******************************
REM ** Start your programs here **
REM ******************************
REM start "" "C:\Users\<userid>\AppData\Roaming\AeroFSExec\aerofs.exe"
REM start "" "C:\Program Files\ownCloud\owncloud.exe"

REM ********************************
REM ** END of Program Start block **
REM ********************************

goto end

:mountfail
echo Truecrypt failed to mount volume.
goto end

:noTC
echo Cant find truecrypt at: %tcexec%
goto end

:NoVolume
echo Identified volume does not exist: %volumefolder%\%volumename%
goto end

:DriveExists
echo Drive letter %mountdrive% already exists, cannot mount truecrypt volume
goto end

:End

Microsoft имеет утилиту (aka "PowerToy") для Windows под названием TweakUI, которая позволяет включать или отключать автозапуск на ваших дисках (под Мой компьютер | автозапуск | диски в левой панели программы TweakUI). Я просто смонтировал том TrueCrypt, и это видно в TweakUI - так что похоже, что я мог бы автозапуск на включить его). К сожалению, я не смогу проверить его дальше, потому что у меня нет автозапуска.inf-файл для воспроизведения).