Можно ли назначить определенный стиль всем перекрестным ссылкам в Word 2007?

• пресс Alt+F9 показать коды полей

• используйте следующий макрос для добавления CHARFORMAT во все перекрестные ссылки. Этот макрос добавляет строку в поле, только если она еще не существует.

  Sub SetCHARFORMAT()
  '
  ' Set CHARFORMAT switch to all {REF} fields. Replace MERGEFORMAT.
  '
  '
      Dim oField As Field
      Dim oRng As Range
      For Each oField In ActiveDocument.Fields
      'For Each oField In Selection.Fields
          If InStr(1, oField.Code, "REF ") = 2 Then
              If InStr(1, oField.Code, "MERGEFORMAT") <> 0 Then
                  oField.Code.Text = Replace(oField.Code.Text, "MERGEFORMAT", "CHARFORMAT")
              End If
              If InStr(1, oField.Code, "CHARFORMAT") = 0 Then
                  oField.Code.Text = oField.Code.Text + "\* CHARFORMAT "
              End If
          End If
      Next oField
  
  
  End Sub
  

• используйте этот макрос для форматирования всех перекрестных ссылок со стилем" тонкая ссылка " (убедитесь, что у вас есть такой стиль, и что показаны коды полей):

  Sub SetCrossRefStyle()
  '
  ' Macro to set styole of all cross references to "Subtle Reference"
  '
  '
      Selection.Find.ClearFormatting
      Selection.Find.Replacement.ClearFormatting
      Selection.Find.Replacement.Style = ActiveDocument.Styles( _
          "Subtle Reference")
      With Selection.Find
          .Text = "^19 REF"
          .Replacement.Text = ""
          .Forward = True
          .Wrap = wdFindContinue
          .Format = True
          .MatchCase = False
          .MatchWholeWord = False
          .MatchKashida = False
          .MatchDiacritics = False
          .MatchAlefHamza = False
          .MatchControl = False
          .MatchWildcards = False
          .MatchSoundsLike = False
          .MatchAllWordForms = False
      End With
      Selection.Find.Execute Replace:=wdReplaceAll
  End Sub
  

• пресс Alt+F9 чтобы скрыть коды полей

редактирование макроса, загруженного киборгом, мы можем легко автоматизировать отображение и скрытие кодов полей. так что каждый раз, когда мы хотим обновить мы не должны использовать коды переключения полей. Я использовал следующий код для добавления переключателя кода поля.

ActiveDocument.ActiveWindow.View.ShowFieldCodes = False

полный макрос выглядит следующим образом:

Sub SetCrossRefStyle()
'
' Macro to set styole of all cross references to "Subtle Reference"
'
'
ActiveDocument.ActiveWindow.View.ShowFieldCodes = True
Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
Selection.Find.Replacement.Style = ActiveDocument.Styles( _
    "Subtle Reference")
With Selection.Find
    .Text = "^19 REF"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindContinue
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchKashida = False
    .MatchDiacritics = False
    .MatchAlefHamza = False
    .MatchControl = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
ActiveDocument.ActiveWindow.View.ShowFieldCodes = False
End Sub

это первый раз, когда я использую макросы для ускорения работы в word. спасибо киборгу за такой полезный макрос.

быстрый и эффективный способ:

1. Выделите текст с форматированием, который вы хотите использовать для ссылки.
2. выберите Home вкладка на ленте.
3. щелкните правой кнопкой мыши на нормальный стиль и выберите обновление нормальное для матча отбора.
4. обновить ссылки с Ctrl + на,F9.