Получить индекс выбранного значения в раскрывающемся списке Excel

Обновлено

попробуйте вставить следующий VBA в "ThisWorkbook" (если вам нужна помощь с этим, спросите в комментарии):

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim ValidationIndex As Long
Dim rngTest As Excel.Range

'assumes the data validation is in a cell named "rngTest"
On Error Resume Next
Set rngTest = Sh.Range("rngTest")
If rngTest Is Nothing Then
    Exit Sub
End If
On Error GoTo 0

If Not Intersect(ActiveCell, Sh.Range("rngTest")) Is Nothing Then
    ValidationIndex = GetValidationIndex
    Sheets("Sheet1").Range("E2").Value = ValidationIndex
End If
End Sub

Function GetValidationIndex() As Long
'returns a 1-based index
Dim rngTest As Excel.Range
Dim varValidationString As Variant
Dim ErrNumber As Long
Dim i As Long

With ActiveCell.Validation
    If .Type = xlValidateList Then    '3
        On Error Resume Next
        Set rngTest = ActiveCell.Parent.Range(.Formula1)
        'I do this goofy thing with ErrNumber to keep my indenting and flow pretty
        ErrNumber = Err.Number
        On Error GoTo 0
        'if the Validation is defined as a range
        If ErrNumber = 0 Then
            GetValidationIndex = Application.WorksheetFunction.Match(ActiveCell.Value2, rngTest, 0)
            Exit Function
        'if the validation is defined by comma-separated values
        Else
            varValidationString = Split(.Formula1, ",")
            For i = LBound(varValidationString) To UBound(varValidationString)
                If varValidationString(i) = ActiveCell.Value2 Then
                    GetValidationIndex = i + 1
                    Exit Function
                End If
            Next i
        End If
    End If
End With
End Function

несколько замечаний:

• это предполагает, что ваш выпадающий список / ячейка называется "rngTest". Если нет, затем переименуйте его или измените его в этом коде на существующее имя.
• строка 15 определяет точную ячейку, в которой будет выведен результат индекса. Вам нужно будет изменить лист и ячейку имена, соответствующие вашим собственным.

Я проверил это, и это работает, хотя я не могу взять полный кредит, поскольку исходный код был чем-то, что я нашел несколько месяцев назад. Если у вас возникли проблемы, иногда проще воспроизвести этот процесс на новом листе, пока вы не поймете, что это теория работы.