Пакетный файл переименовать случайным буквенно-цифровым

следующий простой скрипт переименует все .jpg файлы в текущей папке к случайным 8 символьным буквенно-цифровым именам, сохраняя .расширением jpg. Обратите внимание, что генератор случайных имен может создать имя, которое уже существует, поэтому сценарий будет циклически повторяться до тех пор, пока не будет успешно сгенерировано уникальное имя.

@echo off
setlocal disableDelayedExpansion
set "chars=ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
for /f "eol=: delims=" %%F in ('dir /b /a-d *.jpg') do call :renameFile "%%F"
exit /b

:renameFile
setlocal enableDelayedExpansion
:retry
set "name="
for /l %%N in (1 1 8) do (
  set /a I=!random!%%36
  for %%I in (!I!) do set "name=!name!!chars:~%%I,1!"
)
echo if exist !name!.jpg goto :retry
endlocal & ren %1 %name%.jpg

немного больше кода дает универсальную утилиту, которая позволяет указать исходный путь и маску файла, а также предоставляет возможность обрабатывать подкаталоги также. Утилита всегда сохраняет расширение каждого файла. Будьте осторожны с этой утилитой!

renameFilesRandom.летучая мышь

:: renameFilesRandom.bat  [filter]  [/s]
@echo off
setlocal disableDelayedExpansion

:: Parse and validate arguments
set "option="
set "filter="
if "%~3" neq "" (
  >&2 echo ERROR: Too many arguments
  exit /b 1
)
if /i "%~1" equ "/S" (set "option=/S") else if "%~1" neq "" set "filter=%~1"
if /i "%~2" equ "/S" (set "option=/S") else if "%~2" neq "" (
  if defined filter (
    >&2 echo ERROR: Only one filter allowed
    exit /b 1
  ) else set "filter=%~2"
)
if "%filter:~0,1%" equ "/" (
  >&2 echo ERROR: Invalid option %filter%
  exit /b 1
)
if not defined filter set "filter=*"

:: Convert a directory filter into a file filter with wildcards
if exist "%filter%\" set "filter=%filter%\*"

:: Determine source if /S option not specified
set "src="
if not defined option for /f "eol=: delims=" %%F in ("%filter%") do set "src=%%~dpF"

:: Rename the specified files
set "chars=ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
for /f "eol=: delims=" %%F in ('dir /a-d /b %option% "%filter%"') do call :renameFile "%%F"
exit /b

:renameFile
setlocal
if not defined src set "src=%~dp1"
set "old=%~nx1"
set "ext=%~x1"
setlocal enableDelayedExpansion
:retry
set "name="
for /l %%N in (1 1 8) do (
  set /a I=!random!%%36
  for %%I in (!I!) do set "name=!name!!chars:~%%I,1!"
)
if exist "!src!!name!!ext!" goto :retry
ren "!src!!old!" "!name!!ext!"

Ниже приведены некоторые примеры использования.

переименовать все файлы в текущей директории:

renameFilesRandom

переименовать все .jpg файлы в текущем каталоге:

renameFilesRandom *.jpg

переименовать все .jpg файлы в c:\test папка и все ее подпапки (рекурсивные):

renameFilesRandom c:\test\*.jpg /s