Добавить имя папки в начало имени файла

вы можете сделать это более удобным для пользователя способом, используя ReNamer, С одним правилом переименования:

1. вставить": File_FolderName:_ " как префикс (пропустить расширение)

вы также можете сохранить его как пресет и использовать его для переименование командной строки.

переименовывать только файлы в непосредственных дочерних папках

@echo off
pushd "Folder"
for /d %%D in (*) do (
  for %%F in ("%%~D\*") do (
    for %%P in ("%%F\..") do (
      ren "%%F" "%%~nxP_%%~nxF"
    )
  )
)
popd

рекурсивно переименовать все файлы в папках ребенка

@echo off
pushd "Folder"
for /d %%D in (*) do (
  pushd "%%D"
  for /r %%F in (*) do (
    for %%P in ("%%F\..") do (
      ren "%%F" "%%~nxP_%%~nxF"
    )
  )
  popd
)
popd

убедитесь, что вы запускаете любой скрипт только один раз! Вы не хотите ставить несколько префиксов перед файлами: -)

дополнительный код может быть добавлен, чтобы сделать его безопасным, чтобы запустить несколько раз.

Если вы хотите переименовать файлы в папке только это решение.

for %%f in (.) do set "A=%%~dpnxf\"
for /r "%A%" %%f in (.) do call :func "%%~f"
goto :EOF
:func
set "B=%~1"
for %%g in ("%B%") do set "C=%%~dpnxg"
for %%g in ("%C%") do set "D=%%~nxg"
cd  %C%
set "k=%C%\"
if NOT %A%==%k% FOR %%v IN (*.*) DO REN "%%v" "%D%_%%v" 
goto :EOF