Как заставить Windows 7 не использовать корзину на съемном диске?

но Windows по-прежнему создает Папка "Recycling Bin"

этого довольно легко избежать:

удалить папку, откройте блокнот и сохраните пустой файл как $Recycle.Bin в корневом каталоге рассматриваемого диска Windows не может создать папку.

Если вы хотите снова использовать корзины на этом диске, просто удалите файл.

смонтируйте диск под диск Linux как Clonezilla и сделайте посекторную копию. Таким образом, у вас есть копия, а не оригинал. Я не думаю, что вы можете остановить процесс Windows по умолчанию создания скрытой папки корзины на каждом диске, но многие системы Linux (например, Puppy Linux) не будут касаться диска с операцией записи, пока вы не скажете им.

редактировать: мой плохой я отвечал на другой пост. Однако, если вы загружаете вашу машину Windows с щенок Linux диск, а затем вставьте внешний диск, вы можете удалить ресайклер и переместить mp3 файлы на диск без получения каких-либо нежелательных файлов, записанных на диск. Затем вы можете удалить mp3-диск, удалить диск щенка и перезагрузиться в Windows без особых хлопот. Я не знаю никакого реального способа остановить скрытый файл recycler от броска на диск, но это будет работать вокруг него.

" Как заставить Windows 7 не использовать корзину на съемном диске?"

запускать следующий скрипт при запуске или входе в систему.

Source Windows 7: отключить создание $ recycle.папки bin?:

Да это можно сделать... потому что меня раздражало, что это невозможно сделать, поэтому я написал сценарий, чтобы сделать это (см. ниже). Это работает для меня, но если у вас есть какие-либо вопросы сами вам может понадобиться, чтобы настроить его немного.

' Author:      HSV Guy
' Description: Script to remove Recycle Bin folder. Run on Windows startup or login.
' Notes: 1)    See http://www.sevenforums.com/tutorials/11949-elevated-program-shortcut-without-uac-prompt-create.html
'              for how to run programs/scripts with elevated permissions without a UAC prompt.
'        2)    Update value of RECYCLEBIN as per version of Windows (configured for Windows 7).
' Date:        1 April 2011

Dim SILENT
SILENT = TRUE

Call RunElevated

Dim filesys, drv, drvcoll, folder, RECYCLEBIN
RECYCLEBIN = ":$Recycle.Bin\"

Set filesys = CreateObject("Scripting.FileSystemObject")
Set drvcoll = filesys.Drives


For Each drv in drvcoll
  If drv.IsReady And filesys.FolderExists(drv.DriveLetter & RECYCLEBIN)  Then
     Set folder = filesys.GetFolder(drv.DriveLetter & RECYCLEBIN)
     MyMsgBox "About to delete: " & folder
     folder.Delete
  Else
    MyMsgBox "Skipped " & drv.DriveLetter & ". Folder doesn't exist or device not ready."
  End If  
Next

'Source code of RunElevated function shamelessly taken from:
' http://www.insidethe.com/blog/2009/12/how-to-launch-a-wsh-vbscript-as-administrator-in-windows-7-and-vista/
Function RunElevated
    If WScript.Arguments.Named.Exists("elevated") = False Then
        'Launch the script again as administrator
        CreateObject("Shell.Application").ShellExecute "wscript.exe", """" & WScript.ScriptFullName & """ /elevated", "", "runas", 1
        WScript.Quit
    Else
        'Change the working directory from the system32 folder back to the script's folder.
        Set oShell = CreateObject("WScript.Shell")
        oShell.CurrentDirectory = CreateObject("Scripting.FileSystemObject").GetParentFolderName(WScript.ScriptFullName)
         MyMsgBox "Now running with elevated permissions" & SILENT
    End If
End Function

Function MyMsgBox(Message)
    If Not SILENT Then MsgBox Message
End Function