Powerpoint VBA объединить pptx файлы в один

Я не мог получить один, вы должны работать. Он довольно старый, поэтому, возможно, он не совместим с более поздними версиями PowerPoint.

Я нашел следующий VBA в PPTools, решение 2, которое работает для того чтобы сделать чего вы описали. Единственное исключение, вам не нужно менять путь, потому что он использует папку, в которой находятся файлы, которые вы хотите объединить.

есть два Subs в этом коде, который должен использоваться вместе.

• открыть новый файл презентации и сохранить его в папку со всеми файлами вы хотите объединить находятся в (вы можете переместить его позже)
• вставьте код в окно VBA
• запустить InsertAllSlides макрос и он будет объединять их.

Sub InsertAllSlides()
'  Insert all slides from all presentations in the same folder as this one
'  INTO this one; do not attempt to insert THIS file into itself, though.

    Dim vArray() As String
    Dim x As Long

    ' Change "*.PPT" to "*.PPTX" or whatever if necessary:
    EnumerateFiles ActivePresentation.Path & "\", "*.PPT", vArray

    With ActivePresentation
        For x = 1 To UBound(vArray)
            If Len(vArray(x)) > 0 Then
                .Slides.InsertFromFile vArray(x), .Slides.Count
            End If
        Next
    End With

End Sub

Sub EnumerateFiles(ByVal sDirectory As String, _
    ByVal sFileSpec As String, _
    ByRef vArray As Variant)
    ' collect all files matching the file spec into vArray, an array of strings

    Dim sTemp As String
    ReDim vArray(1 To 1)

    sTemp = Dir$(sDirectory & sFileSpec)
    Do While Len(sTemp) > 0
        ' NOT the "mother ship" ... current presentation
        If sTemp <> ActivePresentation.Name Then
            ReDim Preserve vArray(1 To UBound(vArray) + 1)
            vArray(UBound(vArray)) = sDirectory & sTemp
        End If
        sTemp = Dir$
    Loop

End Sub