PowerPoint-установить время для каждого слайда и отображать общее время презентации?

есть надстройка вы можете скачать, что даст вам то, что вы хотите. Видя, что у вас есть первая часть установки, вы можете использовать это добавить-в для отображения прошедшего времени поверх текущего слайда.

на веб-сайте, на который я ссылался, есть инструкции по установке, но для удобства я включу их здесь.

1. скачать исполняемый файл и дайте ему установить надстройку в папку по умолчанию. Я просканировал исполняемый файл и установленных файлов на вирусы и я могу подтвердить, что они чистые.

2. после установки надстройки откройте PowerPoint и выполните следующие действия:

-2 - > параметры -> надстройки -> (управление выпадающем внизу) выбираем надстройки PowerPoint и перейти

3. в появившемся диалоговом окне выполните следующие действия:

Добавить новый - > выберите таймер TM PowerPoint (Лента UI) - > OK

выше добавим TM вкладка на ленту PowerPoint. В окне настройки таймера вы сможете установить таймер для отображения прошедшего времени. Там же Update Display запись на первой вкладке, поэтому убедитесь, что вы установили, что в 1 секунду (по умолчанию 10 секунд).

Я надеюсь, что это не нарушает этикет, отвечая на мой собственный вопрос, поскольку я знаю, как обидчивые моды могут быть о следующем протоколе. Но я нашел это, что может обеспечить общее время для слайд-шоу. Он основан на времени, установленном для автоматического перехода слайда (переходы->предварительный слайд->после:). В ленте слайд-шоу, вы можете отключить "использовать тайминги", так что вы будете иметь контроль над продвижением слайдов во время презентации.

Это не даст отсчет скользить по взгляд докладчика, но я полагаю, что могу жить без этого и просто ввести ожидаемое время, в которое я должен быть в верхней части моих заметок. Надстройка выше, казалось бы, обеспечивают обратный отсчет на вид докладчика, но я не смогу использовать его на моем месте, так что это не варианты.

Я основал этот макрос отсюда, PowerPoint FAQ. Я немного изменил его, чтобы показать время в формате" 00:00", а общее время внизу вместо отдельного всплывающего окна. К используйте его, просто создайте перейти к просмотр- > макросы, и создать новый макрос "Общее время". Скопируйте и вставьте следующий код:

Sub TotalTimes()

Dim oSld As Slide
Dim strMessage As String
Dim lngTotalTime As Long
Dim strSlideMin As String
Dim strSlidesec As String


' Use this to collect times for ALL slides:
For Each oSld In ActivePresentation.Slides
' Or comment it out and uncomment this to get just the selected slides:
' For Each oSld in ActiveWindow.Selection.SlideRange
    strSlideMin = Format(Int(oSld.SlideShowTransition.AdvanceTime / 60), "00")
    strSlidesec = Format(Int(oSld.SlideShowTransition.AdvanceTime Mod 60), "00")
    strMessage = strMessage _
        & CStr(oSld.SlideNumber) _
        & vbTab _
        & strSlideMin & ":" & strSlidesec _
        & vbCrLf
    lngTotalTime = lngTotalTime + oSld.SlideShowTransition.AdvanceTime
Next oSld

' Comment these out if you don't want to see them
strMessage = strMessage & vbCrLf & "Total" & vbTab & Format(Int(lngTotalTime / 60), "00") & ":" & Format(Int(lngTotalTime Mod 60), "00")
MsgBox strMessage
'MsgBox ("Total time: " & CStr(lngTotalTime))


End Sub

исходный код также включает раздел для записи в текстовый файл, который я вырезал, так как он не отвечал моим потребностям.

Я так очень очень удивлен, MS не имеет эту информацию, доступную в PowerPoint. Похоже, довольно интуитивная информация, которую они включили бы по умолчанию.

есть более элегантные способы сделать это с помощью надстройки, но как насчет этого ... предполагается, что вы используете presenter view, где вы можете увидеть заметки,но вы можете добавить текст на слайд или что-то вместо этого.

Option Explicit
Public StartTime As Date

Sub StartTimer()
    StartTime = Time
    SlideShowWindows(1).View.GotoSlide (SlideShowWindows(1).View.Slide.SlideIndex + 1)
End Sub

Sub ElapsedTime(osh As Shape)

    Dim oNotesText As Shape
    Dim oNextSlide As Slide

    ' what slide are we about to move TO?
    Set oNextSlide = ActivePresentation.Slides(osh.Parent.SlideIndex + 1)

    ' Get a reference to the notes text on that slide (not 100% reliable, but generally works)
    Set oNotesText = oNextSlide.NotesPage.Shapes(2)

    ' Do the time math and add the elapsed time to the notes:
    With oNotesText
        .TextFrame.TextRange.Text = Format(Time - StartTime, "HH:MM:SS") & vbCrLf & .TextFrame.TextRange.Text
    End With

    ' And go to the slide
    SlideShowWindows(1).View.GotoSlide (SlideShowWindows(1).View.Slide.SlideIndex + 1)

End Sub

добавьте фигуру к первому слайду и назначьте ей настройку действия Run Macro: StartTimer Добавьте фигуру к следующему слайду, назначьте ей настройку действия Run Macro: ElapsedTime Скопируйте и вставьте фигуру из слайда 2 в другие слайды презентация.