Переместить открытый документ Excel в отдельное окно

ответ выше, вероятно, будет работать с книгой, отличной от активной книги, что мне и нужно было сделать. Вот что я использовал

убедитесь, что при запуске, что книга доступна только в пример:

Private Sub Workbook_Open()
    If Application.Workbooks.Count > 1 Then  'check if there's >1 open wb's in this instance
        If MsgBox("This workbook will be moved to a new instance of Excel," & vbLf & _
            "so as to not affect performance of your other workbooks.", _
            vbOKCancel + vbInformation + vbDefaultButton1 + vbMsgBoxSetForeground) _
            = vbCancel Then Exit Sub
        Debug.Print Application.Hinstance, "Moving wb to new instance."
        OpenInNewInstance
        Debug.Print Application.Hinstance, "Moved wb to new instance."
    Else
        Debug.Print "This wb is in it's own instance. (#" & Application.Hinstance & ")"
    End If
End Sub

Sub OpenInNewInstance()
    With ThisWorkbook
        .Save                                           'save workbook before making it read-only
        .ChangeFileAccess xlReadOnly                    'make this wb read-only (so the other isn't)
        Shell ("excel.exe /x """ & .FullName & """")    'open current wb in new instance
        .Close                                          'close this workbook
    End With
End Sub

этот код входит в the ThisWorkbook модуль, чтобы при открытии книги немедленно проверить, является ли это единственной открытой книгой в данном экземпляре, и если не:

1. сохранить текущую книгу
2. установить текущий wb как доступный только для чтения (чтобы 2-я копия не была проблемой)
3. оболочка командной строки, чтобы открыть Excel в новом экземпляре (с помощью Excel /x командная строка switch), загрузка другого экземпляра текущей книги
4. закрыть текущую книгу

при необходимости можно использовать пользовательская командная строка при открытии новой экземпляр для передачи инструкций и т. д. В новый экземпляр. Вы также можете рассмотреть плюсы и минусы сокрытия окна приложения для нового экземпляра.