Экспортировать электронную таблицу Excel в текстовый файл фиксированной ширины?

Если у вас есть Office профессиональный, Вы можете открыть файл Excel в Access, а затем экспортировать из Access. Access позволит вам указать макет с фиксированной шириной для экспортируемого файла и предоставит вам очень подробные элементы управления для указания этих Ширин.

Вау, я собирался задать этот вопрос сам, но он уже был задан. Все Excel выходной буфер tab разделитель по умолчанию. Это раздражает для "реального" вывода обычного текста, когда у вас есть шрифт фиксированной ширины, но не обязательно поддержка разделителей табуляции.

во всяком случае, я нашел и изменил небольшой макрос Excel, который скопирует текущую выбранную область в виде простой таблицы ASCII с фиксированной шириной столбцов - например:

187712 201    37     0.18   
2525   580    149    0.25   
136829 137    43     0.31   

вот код макроса. Чтобы использовать его, убедитесь, что вы включить вкладку Разработчик в Excel Options если вы используете Excel 2007 или более поздней.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)

    Dim temp As Integer
    Dim cellsize As Integer
    cellsize = 0
    For c = 1 To selectedcols
        temp = Len(CStr(Cells(1, c)))
        If temp > cellsize Then
            cellsize = temp
        End If
    Next c
    cellsize = cellsize + 1

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(selectedcols * cellsize)
        For c = 1 To selectedcols
            Mid(line, c * cellsize - cellsize + 1, cellsize) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

во-первых, формат данных как курьер новый (или другой моноширинный шрифт). Затем сохраните как .prn и вы получите истинную фиксированную ширину.

расширяя ответ Джеффа Этвуда, так как он не позволил бы мне прокомментировать там:

Я изменил его макрос, чтобы установить ширину столбца на самую широкую ячейку в этом столбце и иметь каждый столбец свою ширину. Его макрос нашел только самую широкую ячейку в первой строке, а затем установил ширину всех столбцов.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long, linesize As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)
    ReDim CellSizes(1 To selectedcols, 2) As Integer

    Dim temp As Integer
    Dim cellsize As Integer
    linesize = 0
    For c = 1 To selectedcols
        cellsize = 0
        For r = 1 To selectedrows
            temp = Len(CStr(Cells(r, c)))
            If temp > cellsize Then
                cellsize = temp
            End If
        Next
        CellSizes(c, 0) = cellsize + 1
        CellSizes(c, 1) = linesize
        linesize = linesize + cellsize + 1
    Next c

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(linesize)
        For c = 1 To selectedcols
            Mid(line, CellSizes(c, 1) + 1, CellSizes(c, 0)) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

Это убийца для меня. Он имеет несколько вариантов, а также.

http://www.sensefulsolutions.com/2010/10/format-text-as-table.html