Excel VBA или Формула для преобразования текста в дату с типом времени

выделите ячейки и выполните команду:

Sub DateFixer()
    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual
    Application.EnableEvents = False
        For Each r In Selection
            v = r.Text
            r.Clear
            r.NumberFormat = "dd/mm/yyyy hh:mm:ss"
            r.Value = DateSerial(Mid(v, 7, 4), Mid(v, 4, 2), Left(v, 2)) + TimeSerial(Mid(v, 12, 2), Mid(v, 15, 2), Right(v, 2))
        Next r
    Application.ScreenUpdating = True
    Application.Calculation = xlCalculationAutomatic
    Application.EnableEvents = True
End Sub

Это сработало для меня

Sub dothis()

Dim row As Integer
row = 0

Dim maxRows As Integer
maxRows = 3

For row = 1 To maxRows
    Range("A" & row).Value = Replace(Range("A" & row).Value, ".", "/")
Next row

End Sub

просто, на ПК Великобритании в любом случае, это не понравилось 25.08.2011 из-за периода (.). Итак, я преобразовать точку на forwardslash.

после этого, я мог бы использовать код =Today(A1) и он распознал дату. Может быть, вам нужно отформатировать ячейки на сегодняшний день после макроса.

для Формулы:

=DATE(MID(A1,7,4),MID(A1,4,2),LEFT(A1,2))+TIME(MID(A1,12,2),MID(A1,15,2),RIGHT(A1,2))

и затем отформатировать его, как вам нравится.

Если вы хотите использовать макрос VBA, предполагается

• ваши данные начинаются с A1 и находятся в столбце a
• результаты будут в столбце B -- но вы можете легко изменить код, чтобы перезаписать, как только вы видите, что он работает нормально
• формат похож на ваши примеры: дата и время разделены одним пробелом; компоненты даты разделены по < точке >; компоненты времени разделяются < двоеточием >

Option Explicit
Sub ConvertDateTimeString()
    Dim vraw, vRes()
    Dim vDT, vTime, V
    Dim DT As Date, TM As Date
    Dim I As Long, S As String

vraw = Range("a1", Cells(Rows.Count, "A").End(xlUp))
    If VarType(vraw) < vbArray Then 'check for only one entry
        ReDim vraw(1 To 1, 1 To 1)
        vraw(1, 1) = [a1]
    End If
ReDim vRes(1 To UBound(vraw), 1 To 1)

For I = 1 To UBound(vraw)
    S = vraw(I, 1)
    vDT = Split(Split(S)(0), ".")
    vTime = Split(Split(S)(1), ":")

    DT = DateSerial(vDT(2), vDT(1), vDT(0))
    vTime = TimeSerial(vTime(0), vTime(1), vTime(2))
    vRes(I, 1) = DT + vTime
Next I

With Range("B1").Resize(UBound(vRes), 1)
    .EntireColumn.Clear
    .Value = vRes
    .NumberFormat = "dd.mm.yyyy hh:mm:ss"
    .EntireColumn.AutoFit
End With
End Sub

Hack: скопируйте весь столбец в буфер обмена, вставьте в блокнот, скопируйте все из блокнота, вставьте обратно в excel. Убедитесь, что формат даты/времени вашего компьютера совпадает с используемым там, иначе excel не будет интерпретировать его.