Как объединить несколько файлов PowerPoint в один файл?

Да, вы можете, но вы не можете сделать это с двоичным добавлением.

почему...??

Поскольку CSV-файл представляет собой файл значений, разделенных запятыми, который позволяет сохранять данные в табличном структурированном формате. Csv выглядят как таблица разнообразия сада, но с A .расширение csv. Поэтому, когда вы добавляете их, вы все равно можете использовать их в excel. Но. pptx имеют разные форматы, которые не так просты. следовательно, бинарное добавление не будет работать.

следующий код вставить все слайды из всех презентаций в папку в качестве текущей активной презентации (но не будет пытаться вставить слайды из текущей презентации в себя). (Лично Проверял)

выполните действия:

1. создать новую папку.

2. для добавления нескольких файлов, сохраните текущий файл в новой папке, в которую вы хотите вставить слайды из других архив.

3. копировать все остальные .pptx или .ppt файлы в новую папку Откройте документ, в который вы хотите добавить файлы.

4. Теперь нажмите ALT+F11, чтобы запустить редактор VBA.

5. или выберите Файл / Параметры | Настройка ленты и поставить галочку рядом с разработчиком в списке в разделе Настройка ленты. Закройте диалоговое окно параметры, нажмите на На вкладке разработчик щелкните Visual Basic, чтобы запустить редактор.

6. в Редакторе VBA убедитесь, что презентация выделена в левой панели.
   
   Выберите Вставить, модуль в строке меню, чтобы вставить новый модуль кода в проект.

7. вставьте этот код и измените"*.PPT "to"*.PPTX " или что угодно, если необходимо

   Sub InsertAllSlides()
   '  Insert all slides from all presentations in the same folder as this one
   '  INTO this one; do not attempt to insert THIS file into itself, though.
   
       Dim vArray() As String
       Dim x As Long
   
       ' Change "*.PPT" to "*.PPTX" or whatever if necessary:
       EnumerateFiles ActivePresentation.Path & "\", "*.PPT", vArray
   
       With ActivePresentation
           For x = 1 To UBound(vArray)
               If Len(vArray(x)) > 0 Then
                   .Slides.InsertFromFile vArray(x), .Slides.Count
               End If
           Next
       End With
   
   End Sub
   
   Sub EnumerateFiles(ByVal sDirectory As String, _
       ByVal sFileSpec As String, _
       ByRef vArray As Variant)
       ' collect all files matching the file spec into vArray, an array of strings
   
       Dim sTemp As String
       ReDim vArray(1 To 1)
   
       sTemp = Dir$(sDirectory & sFileSpec)
       Do While Len(sTemp) > 0
           ' NOT the "mother ship" ... current presentation
           If sTemp <> ActivePresentation.Name Then
               ReDim Preserve vArray(1 To UBound(vArray) + 1)
               vArray(UBound(vArray)) = sDirectory & sTemp
           End If
           sTemp = Dir$
       Loop
   
   End Sub
   

8. чтобы убедиться в отсутствии серьезных синтаксических проблем с кодом, выберите в меню Debug, Compile бар.
9. если есть ошибка, проверьте код еще раз, иначе нажмите кнопку Выполнить.
10. слайды будут добавлены в открытый документ.

Примечание : фоновые изображения и некоторые другие элементы не добавляются при добавлении слайдов из другого файла.

Посмотреть И Узнать Больше :

• вставить все слайды из презентации группы в текущий презентация
• как использовать код VBA в PowerPoint