Текст рабочего стола, который всегда находится сверху и периодически загружается из файла

Я хочу, чтобы пользовательский текст печатался на моем экране всегда сверху. Я пробовал программы Rainmeter и я не мог найти вариант, чтобы загрузить текст из файла в моей системе или каким-либо другим способом.

Что я хочу иметь это программное обеспечение, которое печатает поверх всех окон и сканировать файл каждые секунды, чтобы распечатать последние изменения.

P.S. идея состояла бы в том, чтобы мой живой журнал ошибок сайта PHP печатался на моем экране каждую секунду или по мере появления новых записей.

10
задан karel
09.05.2023 15:50 Количество просмотров материала 3159
Распечатать страницу

1 ответ

мне удалось заставить это работать, но вам, возможно, придется играть с прозрачностью / размером шрифта / цветом фона, чтобы его было легко читать.

вам нужно установить AutoHotKey и запустите этот скрипт: https://www.dropbox.com/s/x510z8tsxunardl/OSDTest.ahk

в коде есть некоторые комментарии, но вкратце это будет: прочитать 5 строк из конца указанного файла журнала; создать окно и добавить его в виде текста в окне; сделайте окно прозрачным, всегда сверху и "unclickable"; и обновляйте текст каждые 1 секунды (возможно, потребуется увеличить это, но я не вижу огромного снижения производительности - даже с файлом журнала размером 20 Мб).

чтобы выйти из скрипта, щелкните правой кнопкой мыши значок AutoHotKey в системном трее и выберите Exit.

Если мои ссылки сломаны, код AHK следующий:

#SingleInstance force
; Example: On-screen display (OSD) via transparent window:
FileName := "C:\xampplite\apache\logs\access.log"
NumLines = 5
CustomColor = FF8080 ; The transparent background color of the window, set this to something close to your text colour to avoid white highlighting

Gui +LastFound +AlwaysOnTop -Caption +ToolWindow +E0x20  ; +ToolWindow avoids a taskbar button and an alt-tab menu item.
Gui, Color, %CustomColor%
Gui, Font, s12  ; Set a large font size (12-point).
errorTail := FileTail(FileName , NumLines) ; get the text from the file, last 5 lines
Gui, Add, Text, vMyText cRed Y+0, %errorTail%  ; add it, colour is Red, R5 sets 5 rows

; choose one of these lines, first one show just the text, second one has a background for readability
WinSet, TransColor, %CustomColor% 200 ; Make all pixels of this color transparent and make the text itself translucent (250)
;Winset, Transparent, 150

SetTimer, UpdateOSD, 1000 ; 1 second timer set here
Gui, Show, x0 y600 NoActivate  ; Set the x and y position. NoActivate avoids deactivating the currently active window.
return

UpdateOSD: ; the repeated timer routine
errorTail := FileTail(FileName, NumLines) ;get 5 lines
GuiControl,, MyText, %errorTail%
return

; ======================================================================================================================
; Function:    Retrieve the last lines of a text file.
; AHK version:  1.1.07+
; Parameters:
;    FileName -  the name of the file, assumed to be in A_WorkingDir if an absolute path isn't specified
;    Lines  -  number of lines to read - default: 10 (like Unix)
;    NewLine  -  new line character(s)   - default: `r`n (Windows)
; Return values:
;    On success: The required lines, if present
;    On failure: ""
; Version:      1.0.00.00/2012-04-16/just me
; ======================================================================================================================
FileTail(FileName, Lines = 10, NewLine = "`r`n") {
   Static MaxLineLength := 256 ; seems to be reasonable to start with
   If !IsObject(File := FileOpen(FileName, "r"))
      Return ""
   Content := ""
   LinesLength := MaxLineLength * Lines * (InStr(File.Encoding, "UTF-16") ? 2 : 1)
   FileLength := File.Length
   BytesToRead := 0
   FoundLines := 0
   While (BytesToRead < FileLength) && !(FoundLines) {
      BytesToRead += LinesLength
      If (BytesToRead < FileLength)
         File.Pos := FileLength - BytesToRead
      Else
         File.Pos := 0
      Content := RTrim(File.Read(), "`r`n")
      If (FoundLines := InStr(Content, NewLine, 0, 0, Lines))
         Content := SubStr(Content, FoundLines + StrLen(NewLine))
   }
   File.Close()
   Return Content
}
0
отвечен Luke 2023-05-10 23:38

Постоянная ссылка на данную страницу: [ Скопировать ссылку | Сгенерировать QR-код ]

Ваш ответ

Опубликуйте как Гость или авторизуйтесь

Имя
Вверх